*  JieJie Microelectronics H-Spice Model Library
*  Filename: JMSH0601ATL_H v.20221012.txt
*  Product Name: JMSH0601ATL (PowerJE®10x12)
*  Configuration: Single N channel Device
*  Data Sheet Rev.: 1.2
*  Release Date: October13, 2022
*  Junction Temp (Tj): -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with commercially available EDA simulation
*  tools End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, Jiangsu JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSH0601ATL D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
RD D 1 0.00098
RS S 3 1E-006
RG G 2 3.0
CGS 3 G 7.42e-9
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 3.2E-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
CDS D 3 POLY 7.05433E-9 -5.05249E-10 5.24432E-11 -3.09197E-12 8.60975E-14 -1.11769E-15 5.50247E-18

.model NMOS NMOS
+LEVEL = 3                     tlev = 1                      tlevc = 0        
+acm = 3                       VMAX = 1.0752E9               ETA = 1.21E-4     
+VTO = 2.405914                TOX = 1.043684E-9             NSUB = 9.6E19      
+KP = 436.20875                U0 = 424                      KAPPA = 0.178      
+GAMMA = 5.10125E-2            PHI = 0.514876                THETA = 2.06002E-2    
+BEX = -0.9                    TCV = 5.4E-4                  DELTA = 236.505608    

.model DCGD D
+CJO = 8.1E-10                 VJ = 9                        M = 1.9      

.model DSUB D
+IS = 1.3344E-11               N = 1.05174                   RS = 1.486204E-3    
+BV = 65                       tlev = 0.14                   tlevc = 0       
+tref = 25                     eg = 1.165047                 keg = 1          
+gap1 = 4.857186E-3            gap2 = 1.108E3                xti = 0.824471      
+cta = 0                       ctp = 0                       tcv = 0          
+tm1 = 0                       tm2 = 0                       tpb = 0        
+tphp = 0                      trs = 0                       ttt1 = 0    
+ttt2 = 0                      xtitun = 3     

.model DLIM D
+IS = 1E-4       
.ends JMSH0601ATL

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************
